ChatController: Add creation and return of chats.

lib/pleroma/chat.ex

@@ -35,6 +35,16 @@ defmodule Pleroma.Chat do
     |> Repo.get_by(user_id: user_id, recipient: recipient)
   end
 
+  def get_or_create(user_id, recipient) do
+    %__MODULE__{}
+    |> creation_cng(%{user_id: user_id, recipient: recipient})
+    |> Repo.insert(
+      on_conflict: :nothing,
+      returning: true,
+      conflict_target: [:user_id, :recipient]
+    )
+  end
+
   def bump_or_create(user_id, recipient) do
     %__MODULE__{}
     |> creation_cng(%{user_id: user_id, recipient: recipient, unread: 1})

lib/pleroma/web/pleroma_api/controllers/chat_controller.ex

@@ -0,0 +1,47 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+defmodule Pleroma.Web.PleromaAPI.ChatController do
+  use Pleroma.Web, :controller
+
+  alias Pleroma.Chat
+  alias Pleroma.Repo
+
+  import Ecto.Query
+
+  def index(%{assigns: %{user: %{id: user_id}}} = conn, _params) do
+    chats =
+      from(c in Chat,
+        where: c.user_id == ^user_id,
+        order_by: [desc: c.updated_at]
+      )
+      |> Repo.all()
+
+    represented_chats =
+      Enum.map(chats, fn chat ->
+        %{
+          id: chat.id,
+          recipient: chat.recipient,
+          unread: chat.unread
+        }
+      end)
+
+    conn
+    |> json(represented_chats)
+  end
+
+  def create(%{assigns: %{user: user}} = conn, params) do
+    recipient = params["ap_id"] |> URI.decode_www_form()
+
+    with {:ok, %Chat{} = chat} <- Chat.get_or_create(user.id, recipient) do
+      represented_chat = %{
+        id: chat.id,
+        recipient: chat.recipient,
+        unread: chat.unread
+      }
+
+      conn
+      |> json(represented_chat)
+    end
+  end
+end

lib/pleroma/web/router.ex

@@ -284,6 +284,13 @@ defmodule Pleroma.Web.Router do
   end
 
   scope "/api/v1/pleroma", Pleroma.Web.PleromaAPI do
+    scope [] do
+      pipe_through(:authenticated_api)
+
+      post("/chats/by-ap-id/:ap_id", ChatController, :create)
+      get("/chats", ChatController, :index)
+    end
+
     scope [] do
       pipe_through(:authenticated_api)
 

test/web/pleroma_api/controllers/chat_controller_test.exs

@@ -0,0 +1,55 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+defmodule Pleroma.Web.PleromaAPI.ChatControllerTest do
+  use Pleroma.Web.ConnCase, async: true
+
+  alias Pleroma.Chat
+
+  import Pleroma.Factory
+
+  describe "POST /api/v1/pleroma/chats/by-ap-id/:id" do
+    test "it creates or returns a chat", %{conn: conn} do
+      user = insert(:user)
+      other_user = insert(:user)
+
+      result =
+        conn
+        |> assign(:user, user)
+        |> post("/api/v1/pleroma/chats/by-ap-id/#{URI.encode_www_form(other_user.ap_id)}")
+        |> json_response(200)
+
+      assert result["id"]
+    end
+  end
+
+  describe "GET /api/v1/pleroma/chats" do
+    test "it return a list of chats the current user is participating in, in descending order of updates",
+         %{conn: conn} do
+      user = insert(:user)
+      har = insert(:user)
+      jafnhar = insert(:user)
+      tridi = insert(:user)
+
+      {:ok, chat_1} = Chat.get_or_create(user.id, har.ap_id)
+      :timer.sleep(1000)
+      {:ok, _chat_2} = Chat.get_or_create(user.id, jafnhar.ap_id)
+      :timer.sleep(1000)
+      {:ok, chat_3} = Chat.get_or_create(user.id, tridi.ap_id)
+      :timer.sleep(1000)
+
+      # bump the second one
+      {:ok, chat_2} = Chat.bump_or_create(user.id, jafnhar.ap_id)
+
+      result =
+        conn
+        |> assign(:user, user)
+        |> get("/api/v1/pleroma/chats")
+        |> json_response(200)
+
+      ids = Enum.map(result, & &1["id"])
+
+      assert ids == [chat_2.id, chat_3.id, chat_1.id]
+    end
+  end
+end